nginx windows管理脚本

cls
@ECHO OFF
SET NGINX_PATH=D:
SET NGINX_DIR=D:\dev-tools\nginx-1.11.13

TITLE Nginx 管理程序
 
CLS
 
ECHO.
ECHO. * * Nginx 管理程序 * * 
ECHO.
 
:MENU
 
ECHO.
    ECHO.  [1] 启动Nginx 
    ECHO.  [2] 停止Nginx 
    ECHO.  [3] 重启Nginx
	ECHO.  [4] 查看Nginx 
	ECHO.  [5] 重载Nginx
    ECHO.  [6] 退 出
ECHO.
 
ECHO.请输入选择项目的序号:
set /p ID=
    IF "%id%"=="1" GOTO start
    IF "%id%"=="2" GOTO stop
    IF "%id%"=="3" GOTO restart
	IF "%id%"=="4" GOTO show
	IF "%id%"=="5" GOTO reload
    IF "%id%"=="6" EXIT
PAUSE

:start
    call :startNginx
    GOTO MENU

:show
    ECHO. * nginx 进程list * 
	tasklist|findstr /i "nginx.exe"
    GOTO MENU
	
:stop
    call :shutdownNginx
    GOTO MENU
	
:reload
    call :reloadNginx
    GOTO MENU
 
:restart
    call :shutdownNginx
    call :startNginx
    GOTO MENU
	
:reloadNginx
	ECHO.
    ECHO.重新载入Nginx......
	
    IF NOT EXIST "%NGINX_DIR%\nginx.exe" (
		ECHO "%NGINX_DIR%\nginx.exe"不存在，请检查路径
		goto :eof
	)
 
    %NGINX_PATH%
 
    cd "%NGINX_DIR%"
 
    IF EXIST "%NGINX_DIR%\nginx.exe" (
        echo "nginx.exe -s reload"
        nginx.exe -s reload
    )
    ECHO.OK
    goto :eof
 
:shutdownNginx
    ECHO.
    ECHO.关闭Nginx......
    taskkill /F /IM nginx.exe > nul
    ECHO.OK,关闭所有nginx 进程
    goto :eof
 
:startNginx
    ECHO.
    ECHO.启动Nginx......
    IF NOT EXIST "%NGINX_DIR%\nginx.exe" ECHO "%NGINX_DIR%\nginx.exe"不存在
 
    %NGINX_PATH%
 
    cd "%NGINX_DIR%"
 
    IF EXIST "%NGINX_DIR%\nginx.exe" (
        echo "start nginx.exe"
        start "" nginx.exe
    )
    ECHO.OK
    goto :eof